**Grammar**

<program> ::= <block>

<block> ::= { <variabledefinition> <slist>} | { <slist> }

<variabledefinition> ::= int <vardeflist> ;

<vardeflist> ::= <vardec> | <vardec> , <vardeflist>

<vardec> ::= <identifier> | <identifier> [ <constant> ]

<slist> ::= <statement> | <statement> ; <slist>

<statement> ::= <assignment> | <ifstatement> | <whilestatement> | <block> | <printstatement> | <empty>

<assignment> ::= <identifier> = <expression> | <identifier> [ <expression> ] = <expression>

<ifstatement> ::= if <bexpression> then <slist> else <slist> endif | if <bexpression> then <slist> endif

<whilestatement> ::= while <bexpression> do <slist> enddo

<printstatement> ::= print ( <expression> )

<expression> ::= <expression> <addingop> <term> | <term> | <addingop><term>

<bexpression> ::= <expression> <relop> <expression>

<relop> ::= < | <= | == | >= | > | !=

<addingop> ::= + | -

<term> ::= <term> <multop> <factor> | <factor>

<multop> ::= \* | /

<factor> ::= <constant> | <identifier> | <identifier> [ <expression>] | ( <expression> )

<constant> ::= <digit> | <digit> <constant>

<identifier> ::= <identifier> <letterordigit> | <letter>

<letterordigit> ::= <letter> | <digit>

<letter> ::= a|b|c|d|e|f|g|h|i|j|k|l|m|n|o|p|q|r|s|t|u|v|w|x|y|z

<digit> ::= 0|1|2|3|4|5|6|7|8|9

<empty> has the obvious meaning